运行截图

文件链接

https://pan.runyf.cn/sh/monitor.bat

源代码展示

@echo off
@title 主机监控
:: by: www.runyf.cn

:: 等待用户输入需要监控IP
set /p ip=请输入IP地址:
:: set ip=
:: 请求成功等待秒数
set waits=3
:: 请求超时等待秒数
set waitf=3

:: 首次执行初始化
set n=0
:: 请求成功计数
set connect=0
:: 请求超时计数
set disconnect=0


:start

:: 设置文件名
set file=%ip%-%date:~0,4%%date:~5,2%%date:~8,2%.txt
:: 设置回显时间格式
set echotime=%date:~0,4%%date:~5,2%%date:~8,2% %time%

:: 循环控制
set /a n+=1
if %n%==1 echo %echotime% 目标地址：%ip% 脚本开始执行... & ^
echo %echotime%  目标地址：%ip% 脚本开始执行... >> %file%

:: 核心代码
:: && 顺序执行多条命令，当碰到执行出错的命令后将不执行后面的命令
:: || 顺序执行多条命令，当碰到执行正确的命令后将不执行后面的命令
ping -n 1 %ip%>nul&&(echo|set /p =%echotime% >>%file% & ^
ping -n 1 %ip% | find "来自">>%file% &  ^
echo|set /p =%echotime% 请求成功& set /a connect+=1 & ^
set /a disconnect=0 & echo 次数：%connect% & ^
timeout /t %waits% > nul) || (^
echo %echotime%  请求超时次数：%disconnect%>>%file% & ^
echo|set /p =%echotime% 请求超时，请注意& set /a disconnect+=1 & ^
set /a connect=0 & echo 次数：%disconnect% & ^
timeout /t %waitf% > nul)

goto start
pause